Audio Manager to handle the loading of sound effects in bulk

# AudioManager Singleton
extends Node

## Tracks all audio files and returns the stream set for a given name
## 
## The goal is to load sets of sound to have variations
##
## The files are named, e.g.: "res://audio/Footsteps/footstep_<set_name>_??.wav"

var streams: Dictionary = {}

@onready
var regex: RegEx = RegEx.new()


## Retrieve an AudioStream
##
func get_stream_set(steam_name: String):
	if streams.has(steam_name):
		return streams.get(steam_name)


func _ready():
	_compile_regex()
	_load_audio(_dir_contents("res://audio/"))

#	# or load them individually
#	var file_list = _dir_contents("res://audio/Footsteps/")
#	file_list.append_array(_dir_contents("res://audio/Animals_Nature_Ambiences/"))
#
#	# recusively loads sub-directories
#	file_list.append_array(_dir_contents("res://audio/Guns_Weapons/"))
#
#	#file_list.append_array(_dir_contents("res://audio/Guns_Weapons/Bullets/"))
#	#file_list.append_array(_dir_contents("res://audio/Guns_Weapons/Guns/"))
#	#file_list.append_array(_dir_contents("res://audio/Guns_Weapons/Guns_Silenced/"))
#	#file_list.append_array(_dir_contents("res://audio/Guns_Weapons/Knife_Sword_Pick/"))
#
#	file_list.append_array(_dir_contents("res://audio/Sci-Fi/"))
#	file_list.append_array(_dir_contents("res://audio/Voice/Human Male A/"))
#	file_list.append_array(_dir_contents("res://audio/Whooshes/"))
#	_load_audio(file_list)


func _dir_contents(path: String) -> Array[String]:
	var file_list : Array[String] = []
	var dir = DirAccess.open(path)
	if dir:
		dir.list_dir_begin()
		var file_name = dir.get_next()
		while file_name != "":
			if dir.current_is_dir():
				# recursively dive in
				file_list.append_array(_dir_contents("%s%s/" % [path, file_name]))
			else:
				if file_name.ends_with(".wav"):
					file_list.push_back(path + file_name)
			file_name = dir.get_next()
	else:
		print_debug("An error occurred when trying to access path: %s." % [path])
	return file_list


func _load_audio(files: Array):
	
	for f in files:
		var asr: AudioStreamRandomizer = _get_stream_set_for_filename(f)
		var stream = AudioStreamWAV.new()

		var file = FileAccess.open(f, FileAccess.READ)
		stream.data = file.get_buffer(file.get_length())
		# file.close()
		
		stream.format = AudioStreamWAV.FORMAT_16_BITS
		stream.mix_rate = 48000
		stream.stereo = true
		
		asr.add_stream(-1, stream)
		if asr.streams_count > 3:
			asr.playback_mode = AudioStreamRandomizer.PLAYBACK_RANDOM_NO_REPEATS
			pass


## Regular Expression that extracts elements from the filename
## E.g. Guns_Weapons/Guns/gun_pistol_shot_01.wav
## becomes:
## - category: gun
## - name: pistol_shot
## - digit: 01
func _compile_regex():
	var result = regex.compile("(?<category>[a-z]+)_(?<name>[0-9a-z_]+)_(?<digit>[0-9a-f]+)\\.wav")
	if result != OK: print_debug("AudioManager cannot compile regex.")


func _get_stream_set_for_filename(filename: String) -> AudioStream:
	# for example: "res://audio/Footsteps/footstep_metal_high_run_02.wav"
	var result = regex.search(filename)
	var stream_name = "_junk"
	if result:
		stream_name = result.get_string("name")
	else:
		# print_debug("Filename %s doesn't match the pattern." % filename)
		pass
	
	if !streams.has(stream_name):
		var rand: AudioStreamRandomizer = AudioStreamRandomizer.new()
		# rand.playback_mode = AudioStreamRandomizer.PLAYBACK_SEQUENTIAL
		rand.playback_mode = AudioStreamRandomizer.PLAYBACK_RANDOM
		rand.random_pitch = 1
		streams[stream_name] = rand
		
	return streams.get(stream_name)